Red [
	Title:   "Test images operators Red VID "
	Author:  "Francois Jouen - Didier Cadieu"
	File: 	 %opimage.red
	Needs:	 'View
]

;
fileName: ""
isFile: false

; all we need for computer vision with red
#include %libs/redcv.red ; for red functions


;interface
rimg: make image!  reduce [512x512 black]
rimg2: make image! reduce [512x512 black]

loadImage: does [
	isFile: false
	canvas/image/rgb: black
	canvas/size: 0x0
	tmp: request-file
	if not none? tmp [
		fileName: to string! to-local-file tmp
		win/text: fileName
		rimg: load tmp
		;generate random image
		rimg2: rcvRandom rimg 127.127.100.0
		; update faces
		win/size/x: 20 + max 500 rimg/size/x
		win/size/y: 50 + max 150 rimg/size/y
		canvas/size: rimg/size
;		canvas/image/size: canvas/size
		canvas/image: rimg
		isFile: true
		op/selected: 1
		op2/selected: 1
		op3/selected: 1
	]
]

img-convert: func [num [integer!]] [
	op2/selected: 1
	op3/selected: 1
	switch num [
		1 	[canvas/image: rimg]
		2 	[canvas/image: rcv2Gray/average rimg ]
		3 	[canvas/image: rcv2Gray/luminosity rimg ]
		4 	[canvas/image: rcv2Gray/lightness rimg ]
		5 	[canvas/image: rcv2BW rimg 127.127.127.0]
		6 	[canvas/image: rcv2BGRA rimg]
		7   [canvas/image: rcv2BGRA rcvReverse rimg]
	]
]

img-logical: func [num [integer!]] [
	op/selected: 1
	op3/selected: 1
	switch num [
			1  [canvas/image: rimg]
			2  [canvas/image: rcvAND rimg rimg2]
			3  [canvas/image: rcvNAND rimg rimg2]
			4  [canvas/image: rcvOR rimg rimg2]
			5  [canvas/image: rcvNOR rimg rimg2]
			6  [canvas/image: rcvXOR rimg rimg2]
			7  [canvas/image: rcvNXor rimg rimg2]
			8  [canvas/image: rcvNot rimg]
			9  [canvas/image: rcvAndS rimg 255.0.0.0]
			10 [canvas/image: rcvAndS rimg 0.255.0.0]
			11 [canvas/image: rcvAndS rimg 0.0.255.0]
			12 [canvas/image: rcvORS rimg 0.255.0.0]
			13 [canvas/image: rcvXORS rimg 0.255.0.0]
			14 [canvas/image: rcvMin rimg2 rimg]
			15 [canvas/image: rcvMax rimg2 rimg]
			16 [canvas/image: rcvInvert rimg]
	]
]

img-math: func [num [integer!]] [
	op/selected: 1
	op2/selected: 1
	switch num [
		1 	[canvas/image: rimg]
		2   [canvas/image: rcvAdd rimg rimg2]
		3   [canvas/image: rcvSub rimg2 rimg]
		4   [canvas/image: rcvMul rimg rimg2]
		5   [canvas/image: rcvDiv rimg rimg2]
		6	[canvas/image: rcvMod rimg rimg2]
		7	[canvas/image: rcvRem rimg rimg2]
		8 	[canvas/image: rcvAddS rimg 128]
		9 	[canvas/image: rcvSubS rimg 64]
		10 	[canvas/image: rcvMulS rimg 2]
		11 	[canvas/image: rcvDivS rimg 2]
		12 	[canvas/image: rcvModS rimg 128]
		13 	[canvas/image: rcvRemS rimg 64]
		14 	[canvas/image: rcvPow rimg 2]
		15 	[canvas/image: rcvLSH rimg 2]
		16 	[canvas/image: rcvRSH rimg 4]
		17 	[canvas/image: rcvAddT rimg 128.128.128.0]
		18 	[canvas/image: rcvSubT rimg 128.128.128.0]
		19  [canvas/image: rcvAbsDiff rimg rimg2]
	]
]

view win: layout [
	title "Red view"
	origin 10x10 space 10x10

	style btn: button -1x22
	style drop-d: drop-down 120x24 on-create [face/selected: 1]

	btn "Load" [loadImage]
	op: drop-d data [
		"Conversions" "GrayScale/Average" "GrayScale/Luminosity" "GrayScale/lightness"
		"Black and White"  "RGB to BGR" "Up Down Flip"
	] select 1 on-change [if isFile [img-convert face/selected]]
	op2: drop-d data [
		"Logical" "And Images" "Nand images" "Or Images"  "Nor Images " "Xor Images"  "NXor Images" "Not Image"
		"And Red" "And Green" "And Blue""Or Green" "Xor Green" "Min Images" "Max Images" "Invert Image"
	] select 1 on-change [if isFile [img-logical face/selected]]
	op3: drop-d data [
		"Math" "Add Images" "Substract Images" "Multiply Images" "Divide Images" "Modulo images" "Remainder Images"
		"Add Scalar (128)" "Substract Scalar (64)" "Multiply by 2"
		"Divide by 2" "Modulo 128" "Remainder 2" "Power 2" "Left Shift 2" "Right Shift 4"
		"Add 128.128.128.0" "Sub 128.128.128.0" "Abs Diff Images"
	] select 1 on-change [if isFile [img-math face/selected]]
	btn "Quit" [quit]
	return
	canvas: base rimg
]

Red [
	Title:   "Test images operators Red VID "
	Author:  "Francois Jouen - Didier Cadieu"
	File: 	 %opimage.red
	Version: 1.2.0
	Needs:	 'View
]

; all we need for computer vision with red
#include %libs/redcv.red ; for red functions


isFile: false
margins: 10x10
system/view/auto-sync?: no

;interface
rimg: make image!  reduce [512x512 black]
rimg2: make image! reduce [512x512 black]
testimg: make image! reduce [512x512 black]

loadImage: does [
	isFile: false
	canvas/image: none
	;canvas/size: 0x0
	tmp: request-file
	if not none? tmp [
		rimg: load tmp
		; if image does not fit screen, scale it
		scale: max 1 1 + max (2 * margins/x + rimg/size/x) / system/view/screens/1/size/x (4 * margins/y + sInfo/size/y + op1/size/y + rimg/size/y) / system/view/screens/1/size/y
		win/text: append append append to string! to-local-file tmp "(1:" scale ")"
		;generate random image
		rimg2: rcvRandom rimg/size 127.127.100.0
		testimg: rcvRandom rimg/size 255.255.255.0
		; redim window with min size
		win/size/x: 2 * margins/x + max 500 rimg/size/x / scale
		win/size/y: 4 * margins/y + sInfo/size/y + op1/size/y + max 150 rimg/size/y / scale
		; redim image view
		canvas/size: rimg/size / scale
		canvas/image: rimg
		; update bottom positions and infos
		sInfo/offset/y: win/size/y - margins/y - sInfo/size/y
		sBar1/text: form rimg/size
		sBar2/text: form rcvMeanImage rimg
		sBar3/text: form scale
		isFile: true
		; reset operation selectors to none
		do-operation none
		;foreach combo [op1 op2 op3] [set in get :combo 'selected 1]
	]
	show win
]

; List of opérations
operations: [
	conversion [
		"Conversions"			[rimg]
		"GrayScale/Average"		[rcv2Gray/average rimg ]
		"GrayScale/Luminosity"	[rcv2Gray/luminosity rimg ]
		"GrayScale/lightness"	[rcv2Gray/lightness rimg ]
		"Black and White"		[rcv2BW rimg]
		"Red Channel"			[rcvSplit/red rimg]
		"Green Channel"			[rcvSplit/green rimg]
		"Blue Channel"			[rcvSplit/blue rimg]
		"RGB => BGR"			[rcv2BGRA rimg]
		"RBG => XYZ"			[rcvRGB2XYZ rimg testimg: canvas/image]
		"XYZ => RGB"			[rcvXYZ2RGB testimg]
		"Up Down Flip"			[rcvFlip/vertical rimg]
		"Left Right Flip"		[rcvFlip/horizontal rimg]
		"V&H Flip"				[rcvFlip/vertical rcvFlip/horizontal rimg]
	]
	logical [
		"Logical"	  		[rimg]
		"And Images"		[rcvAND rimg rimg2]
		"Nand images"		[rcvNAND rimg rimg2]
		"Or Images"			[rcvOR rimg rimg2]
		"Nor Images"		[rcvNOR rimg rimg2]
		"Xor Images"		[rcvXOR rimg rimg2]
		"NXor Images"		[rcvNXor rimg rimg2]
		"Not Image"			[rcvNot rimg]
		"And Red"			[rcvAndS rimg 255.0.0.0]
		"And Green"			[rcvAndS rimg 0.255.0.0]
		"And Blue"			[rcvAndS rimg 0.0.255.0]
		"Or Green"			[rcvORS rimg 0.255.0.0]
		"Xor Green"			[rcvXORS rimg 0.255.0.0]
		"Min Images"		[rcvMin rimg2 rimg]
		"Max Images"		[rcvMax rimg2 rimg]
		"Invert Image"		[rcvInvert rimg]
	]
	math [
		"Math"					[rimg]
		"Add Images"			[rcvAdd rimg rimg2]
		"Substract Images"		[rcvSub rimg2 rimg]
		"Multiply Images"		[rcvMul rimg rimg2]
		"Divide Images"			[rcvDiv rimg rimg2]
		"Modulo images"			[rcvMod rimg rimg2]
		"Remainder Images"		[rcvRem rimg rimg2]
		"Add Scalar (128)"		[rcvAddS rimg 128]
		"Substract Scalar (64)"	[rcvSubS rimg 64]
		"Multiply by 2"			[rcvMulS rimg 2]
		"Divide by 2"			[rcvDivS rimg 2]
		"Modulo 128"			[rcvModS rimg 128]
		"Remainder 2"			[rcvRemS rimg 64]
		"Power 2"				[rcvPow rimg 2]
		"Left Shift 2" 			[rcvLSH rimg 2]
		"Right Shift 4"			[rcvRSH rimg 4]
		"Add 128.128.128.0"		[rcvAddS rimg 128.128.128.0]
		"Sub 128.128.128.0"		[rcvSubS rimg 128.128.128.0]
		"Abs Diff Images"		[rcvAbsDiff rimg rimg2]
	]
]


do-operation: func [face [object! none!]] [
	; reset all combo to 1 but the used one
	foreach combo [op1 op2 op3] [unless same? face combo: get combo [combo/selected: 1]]
	show win
	; no image: exit
	if any [not isFile  none? face] [exit]
	num: face/selected
	ope: face/extra
	; apply the choosed treatment
	canvas/image: do select operations/:ope face/data/:num
	show win
]

view win: layout [
	title "Red view"
	origin margins space margins

	style btn: button -1x22
	style drop-d: drop-down 120x24 on-create [
		ope: face/extra
		face/data: extract operations/:ope 2
		face/selected: 1
	] on-change [do-operation face face/extra]
	style fld: field 100x20
	style txt: text middle -1x20

	btn "Load" [loadImage]
	op1: drop-d do [op1/extra: 'conversion]
	op2: drop-d do [op2/extra: 'logical]
	op3: drop-d do [op3/extra: 'math]
	btn "Quit" [quit]
	return
	canvas: base rimg return
	sInfo: panel [origin 0x0 txt "Image size:" sBar1: fld txt "Image mean value:" sBar2: fld 80 txt "Scale" sBar3: fld 30x20]
]

split: function[source [image!] channel [integer!] return: [image!]][
	rgb1: extract/index source/rgb 3 1
	rgb2: extract/index source/rgb 3 2
	rgb3: extract/index source/rgb 3 3
	rgb: rgb1
	append rgb rgb2
	append rgb rgb3
	w: round(source/size/x / 1)
	h: round(source/size/y / 1)
	
	img: make image! reduce [as-pair w h rgb]
	
	img
]