;===========================================================================
; Redéfinition de l'appel d'un mot clé système : parse
traiter: get in system/words 'parse
; Définition d'une fonction (simplifiée) qui calcule la mensualité du crédit demandé 
calculer-mensualite: func [duree [integer!] montant [money!]] [
  montant / duree	
]
; DĂ©finition d'une fonction qui calcul simplement le taux d'endettement
; en comparant la mensualité par rapport au salaire
calculer-taux-endettement: func [salaire [money!] mensualite [money!]] [
  ((mensualite * 100) / salaire)
]
; Règles d'évaluation d'une demande de crédit
regles-demande-credit: [
  ; Le mot clé 'some indique que l'on pourra avoir plusieurs demandes de crédit à la suite à évaluer
  some [
    ; Définition de la manière dont une demande de crédit doit être formulée
    'demande 'de 'credit 'de set demandeur [string!]
    'pour 'un 'montant 'de set montant [money!]
    'sur 'une 'duree 'de set duree [integer!] set typeduree ['mois | 'ans]
    'avec 'un 'salaire 'de set salaire [money!]
    ; Partie évaluation de la demande de crédit
    (			
      ; On peut effectuer la demande de crédit en précision la durée en mois 
      ; ou en année. Dans ce dernier cas, il faut le ramener en mois car
      ; on calcule le taux d'endettement par rapport au salaire mensuel
      if typeduree = 'ans [duree: duree * 12]
      ; Appel aux fonctions définies plus haut pour calculer la mensualité de la demande
      ; de crédit et le taux d'endettement avec la mensualité
        taux-endettement: calculer-taux-endettement salaire mensualite: calculer-mensualite duree montant
      ; Si/sinon pour la règle d'acceptation de la demande de crédit
      ; si le taux d'endettement est supérieur à 33% la demande de crédit est refusée,
      ; on affiche le refus et le taux d'endettement
      ; sinon la demande de crédit est acceptée,
      ; on affiche la mensualité du crédit. 
      either taux-endettement > ((1 / 3) * 100) [
        print rejoin [
          "La demande de crédit de " demandeur " est refusée !" newline
          "Dépassement du taux d'endettement autorisée de 33% (" taux-endettement " %)."
        ]
      ][
        print rejoin [
          "La demande de crédit de " demandeur " est acceptée !" newline
          "Montant de la demande : " montant "." newline
          "Mensualité de " mensualite " sur " duree " mois."
        ]
      ]
    )
  ]
]
; Exemple simple d'une demande de crédit
dossier-001: [
  demande de credit de "M. Pierre DUPONT"
  pour un montant de EUR$200000
  sur une duree de 15 ans
  avec un salaire de EUR$5000
]
; Exemple avec plusieurs demandes de crédit
mes-dossiers: [
  demande de credit de "M. Alain DURAND"
  pour un montant de $500000
  sur une duree de 20 ans
  avec un salaire de $10000
  demande de credit de "M. Jean DUMONT"
  pour un montant de EUR$40000
  sur une duree de 7 ans
  avec un salaire de EUR$1000
]
; Traitement des dossiers de crédit avec les règles de demande de crédit établies plus haut
traiter dossier-001 regles-demande-credit
traiter mes-dossiers regles-demande-credit
; RĂ©sultats :
; >> traiter dossier-001 regles-demande-credit
; La demande de crédit de M. Pierre DUPONT est acceptée !
; Montant de la demande : EUR$200000.00.
; Mensualité de EUR$1111.11 sur 180 mois.
; >> traiter mes-dossiers regles-demande-credit
; La demande de crédit de M. Alain DURAND est acceptée !
; Montant de la demande : $500000.00.
; Mensualité de $2083.33 sur 240 mois.
; La demande de crédit de M. Jean DUMONT est refusée !
; Dépassement du taux d'endettement autorisée de 33% (47.6190476190476 %).
;===========================================================================